ESP-WROOM-02でWiFi通信、その3、SSLでHTTPSリクエストしてみた

スケッチ例のサンプルESP8266WiFi -> HTTPSRequestを元にHTTPSでリクエストを投げてみた。

3秒間に一回、SSL経由でPOSTデータを投げている。

尚、送信先のサーバーには、Let's encryptを設定済みだ。

www.101010.fun

#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>

const char* ssid = "Router SSID";
const char* password = "Router Password";

const char* host = "example.com";
const int httpsPort = 443;

void setup() {
  Serial.begin(115200);

  wifiInitialize();

}

void loop() {  
  String url = "/somedir/echo.php";
  String postData = "message=88888";
  httpsPost(url, postData);

  delay(3000);
}

void wifiInitialize() {
  Serial.println();
  Serial.print("connecting to ");
  Serial.println(ssid);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void httpsPost(String url, String postData) {
  // Use WiFiClientSecure class to create TLS connection
  WiFiClientSecure client;
  Serial.print("connecting to ");
  Serial.println(host);
  if (!client.connect(host, httpsPort)) {
    Serial.println("connection failed");
    return;
  }

  Serial.print("requesting URL: ");
  Serial.println(url);

  client.println("POST " + url + " HTTP/1.1");
  client.println("Host: " + (String)host);
  client.println("User-Agent: ESP8266/001");
  client.println("Connection: close");
  client.println("Content-Type: application/x-www-form-urlencoded;");
  client.print("Content-Length: ");
  client.println(postData.length());
  client.println();
  client.println(postData);

  Serial.println("request sent");
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") {
      Serial.println("headers received");
      break;
    }
  }
  String line = client.readStringUntil('\n');
  Serial.println("reply was:");
  Serial.println("==========");
  Serial.println(line);
  Serial.println("==========");
  Serial.println("closing connection");
}

サーバー側のスクリプトはこちら、いたって簡単な処理だ。

<?php

$message = $_POST["message"];
$useragent = $_SERVER['HTTP_USER_AGENT'];

echo "Your message is \"". $message. ", UserAgent is \"". $useragent. "\"\n";

?>

f:id:araemonz:20181126132308j:plain

GETでパラメーターを渡してしまうと、SSLの意味がないと思うのでPOSTで送信した。

これを元にセンサの値をサーバーへ投げて、サーバー側ではUnixtimestampと共にデータをログって行こうと思う。